mirror of
https://github.com/kossLAN/dots.git
synced 2025-11-04 22:49:50 -05:00
Initial commit
remove syncthing folder bar/popops: fix menu window anims and positioning bar/popops: change anims a little and add dropshadow Update README.md widgets/coloredicon: move to colorization, looks worse but..., yea bar/popops: make popup window dissapear on menu close README: add todo list, and brief desc Update README.md Update README.md Update README.md bar/systray: issue recreate on interact bar/systray: hide popup on interact bar/systray: add arrow for entries with children bar/battery: start of battery widget wallpaper/matugen: add foot template extra sizing conditions for sys tray bar/systray: add some more margin to text update settings schema bar/workspaces: filter by monitor, switch to scriptmodel settings: fix settings lol bar/systray: fix right item feat: screenshot tool clipboard one day... feat: init lockscreen mpris: add ipc handler for multimedia keys mpris stuff save progress put shell in subdir, and add nix package move readme back woops bar/volume: make tool bar smaller greeter: init greeter greeter: fixed resource links readme: update checklist progress maybe, maybe not fix: fixed screenshot tool not working fix: bar layout issues progress save progress update track styled popup still broken but getting there still broken but getting there fix: gitignore qmlls.ini fix: remove qmlls.ini progress save new popup system new popup system new popup system more work on popups fix: mask issues on popups update readme
This commit is contained in:
commit
9e44812e93
SSH key fingerprint:
SHA256:bdV0x+wdQHGJ6LgmstH3KV8OpWY+OOFmJcPcB0wQPV8
102 changed files with 4592 additions and 0 deletions
53
shell/lockscreen/Controller.qml
Normal file
53
shell/lockscreen/Controller.qml
Normal file
|
|
@ -0,0 +1,53 @@
|
|||
pragma Singleton
|
||||
pragma ComponentBehavior: Bound
|
||||
|
||||
import QtQuick
|
||||
import Quickshell
|
||||
import Quickshell.Io
|
||||
import Quickshell.Wayland
|
||||
import ".."
|
||||
|
||||
Singleton {
|
||||
id: root
|
||||
|
||||
PersistentProperties {
|
||||
id: persist
|
||||
property bool locked: false
|
||||
}
|
||||
|
||||
IpcHandler {
|
||||
target: "lockscreen"
|
||||
|
||||
function lock(): void {
|
||||
persist.locked = true;
|
||||
}
|
||||
}
|
||||
|
||||
LockContext {
|
||||
id: context
|
||||
|
||||
Connections {
|
||||
target: context.state
|
||||
|
||||
function onUnlocked() {
|
||||
persist.locked = false;
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
WlSessionLock {
|
||||
id: lock
|
||||
locked: persist.locked
|
||||
|
||||
WlSessionLockSurface {
|
||||
LockSurface {
|
||||
state: context.state
|
||||
wallpaper: ShellSettings.settings.wallpaperUrl
|
||||
anchors.fill: parent
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
function init() {
|
||||
}
|
||||
}
|
||||
39
shell/lockscreen/GreeterContext.qml
Normal file
39
shell/lockscreen/GreeterContext.qml
Normal file
|
|
@ -0,0 +1,39 @@
|
|||
import QtQuick
|
||||
import Quickshell
|
||||
import Quickshell.Services.Greetd
|
||||
import "../lockscreen"
|
||||
|
||||
Scope {
|
||||
id: root
|
||||
signal launch
|
||||
|
||||
property LockState state: LockState {
|
||||
onTryUnlock: {
|
||||
this.unlockInProgress = true;
|
||||
|
||||
// TODO: env var for user
|
||||
Greetd.createSession("koss");
|
||||
}
|
||||
}
|
||||
|
||||
Connections {
|
||||
target: Greetd
|
||||
|
||||
function onAuthMessage(message: string, error: bool, responseRequired: bool, echoResponse: bool) {
|
||||
if (responseRequired) {
|
||||
Greetd.respond(root.state.currentText);
|
||||
} // else ignore - only supporting passwords
|
||||
}
|
||||
|
||||
function onAuthFailure() {
|
||||
root.state.currentText = "";
|
||||
root.state.failed();
|
||||
root.state.unlockInProgress = false;
|
||||
}
|
||||
|
||||
function onReadyToLaunch() {
|
||||
root.state.unlockInProgress = false;
|
||||
root.launch();
|
||||
}
|
||||
}
|
||||
}
|
||||
48
shell/lockscreen/LockContext.qml
Normal file
48
shell/lockscreen/LockContext.qml
Normal file
|
|
@ -0,0 +1,48 @@
|
|||
pragma ComponentBehavior: Bound
|
||||
|
||||
import QtQuick
|
||||
import Quickshell
|
||||
import Quickshell.Services.Pam
|
||||
|
||||
Scope {
|
||||
id: root
|
||||
|
||||
property LockState state: LockState {
|
||||
onTryUnlock: {
|
||||
if (this.currentText === "")
|
||||
return;
|
||||
|
||||
this.unlockInProgress = true;
|
||||
pam.start();
|
||||
}
|
||||
}
|
||||
|
||||
PamContext {
|
||||
id: pam
|
||||
|
||||
// Its best to have a custom pam config for quickshell, as the system one
|
||||
// might not be what your interface expects, and break in some way.
|
||||
// This particular example only supports passwords.
|
||||
configDirectory: "pam"
|
||||
config: "password.conf"
|
||||
|
||||
// pam_unix will ask for a response for the password prompt
|
||||
onPamMessage: {
|
||||
if (this.responseRequired) {
|
||||
this.respond(root.state.currentText);
|
||||
}
|
||||
}
|
||||
|
||||
// pam_unix won't send any important messages so all we need is the completion status.
|
||||
onCompleted: result => {
|
||||
if (result == PamResult.Success) {
|
||||
root.state.unlocked();
|
||||
root.state.currentText = "";
|
||||
} else {
|
||||
root.state.showFailure = true;
|
||||
}
|
||||
|
||||
root.state.unlockInProgress = false;
|
||||
}
|
||||
}
|
||||
}
|
||||
12
shell/lockscreen/LockState.qml
Normal file
12
shell/lockscreen/LockState.qml
Normal file
|
|
@ -0,0 +1,12 @@
|
|||
import Quickshell
|
||||
|
||||
Scope {
|
||||
property string currentText: ""
|
||||
property bool unlockInProgress: false
|
||||
property bool showFailure: false
|
||||
signal unlocked
|
||||
signal failed
|
||||
signal tryUnlock
|
||||
|
||||
onCurrentTextChanged: showFailure = false
|
||||
}
|
||||
197
shell/lockscreen/LockSurface.qml
Normal file
197
shell/lockscreen/LockSurface.qml
Normal file
|
|
@ -0,0 +1,197 @@
|
|||
pragma ComponentBehavior: Bound
|
||||
|
||||
import QtQuick
|
||||
import QtQuick.Layouts
|
||||
import QtQuick.Controls
|
||||
import Qt5Compat.GraphicalEffects
|
||||
|
||||
Item {
|
||||
id: root
|
||||
required property LockState state
|
||||
required property string wallpaper
|
||||
|
||||
Item {
|
||||
anchors.fill: parent
|
||||
|
||||
Image {
|
||||
id: bgImage
|
||||
source: root.wallpaper
|
||||
fillMode: Image.PreserveAspectCrop
|
||||
anchors.fill: parent
|
||||
visible: false
|
||||
}
|
||||
|
||||
FastBlur {
|
||||
anchors.fill: bgImage
|
||||
source: bgImage
|
||||
radius: 80
|
||||
transparentBorder: false
|
||||
}
|
||||
|
||||
Rectangle {
|
||||
anchors.fill: parent
|
||||
color: "black"
|
||||
opacity: 0.3
|
||||
}
|
||||
|
||||
Rectangle {
|
||||
anchors.fill: parent
|
||||
color: "transparent"
|
||||
|
||||
gradient: Gradient {
|
||||
GradientStop {
|
||||
position: 0.0
|
||||
color: Qt.rgba(0, 0, 0, 0.2)
|
||||
}
|
||||
GradientStop {
|
||||
position: 0.5
|
||||
color: Qt.rgba(0, 0, 0, 0.1)
|
||||
}
|
||||
GradientStop {
|
||||
position: 1.0
|
||||
color: Qt.rgba(0, 0, 0, 0.4)
|
||||
}
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
// Date and time display
|
||||
ColumnLayout {
|
||||
anchors {
|
||||
horizontalCenter: parent.horizontalCenter
|
||||
top: parent.top
|
||||
topMargin: 120
|
||||
}
|
||||
spacing: 10
|
||||
|
||||
Text {
|
||||
id: clock
|
||||
horizontalAlignment: Text.AlignHCenter
|
||||
renderType: Text.NativeRendering
|
||||
font.pointSize: 72
|
||||
font.weight: Font.Light
|
||||
color: "white"
|
||||
text: {
|
||||
const now = this.date;
|
||||
let hours = now.getHours();
|
||||
const minutes = now.getMinutes().toString().padStart(2, '0');
|
||||
const ampm = hours >= 12 ? 'PM' : 'AM';
|
||||
hours = hours % 12;
|
||||
hours = hours ? hours : 12; // 0 should be 12
|
||||
return `${hours}:${minutes}`;
|
||||
}
|
||||
|
||||
property var date: new Date()
|
||||
Layout.alignment: Qt.AlignHCenter
|
||||
|
||||
Timer {
|
||||
running: true
|
||||
repeat: true
|
||||
interval: 1000
|
||||
onTriggered: clock.date = new Date()
|
||||
}
|
||||
|
||||
layer.enabled: true
|
||||
layer.effect: DropShadow {
|
||||
horizontalOffset: 0
|
||||
verticalOffset: 0
|
||||
radius: 20
|
||||
samples: 41
|
||||
color: Qt.rgba(1, 1, 1, 0.3)
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
// login section
|
||||
ColumnLayout {
|
||||
visible: Window.active
|
||||
anchors.centerIn: parent
|
||||
spacing: 30
|
||||
|
||||
Rectangle {
|
||||
id: profileImage
|
||||
Layout.alignment: Qt.AlignHCenter
|
||||
Layout.preferredWidth: 120
|
||||
Layout.preferredHeight: 120
|
||||
|
||||
layer.enabled: true
|
||||
layer.effect: OpacityMask {
|
||||
maskSource: Rectangle {
|
||||
width: profileImage.width
|
||||
height: profileImage.height
|
||||
radius: width / 2
|
||||
color: "black"
|
||||
}
|
||||
}
|
||||
|
||||
Image {
|
||||
source: "root:resources/general/pfp.png"
|
||||
anchors.fill: parent
|
||||
}
|
||||
}
|
||||
|
||||
// password input, should probably split this out into a seperate comp
|
||||
LoginField {
|
||||
id: passwordBox
|
||||
enabled: !root.state.unlockInProgress
|
||||
|
||||
Layout.preferredWidth: 250
|
||||
Layout.preferredHeight: 30
|
||||
Layout.maximumHeight: 30
|
||||
Layout.alignment: Qt.AlignHCenter
|
||||
|
||||
onTextChanged: root.state.currentText = this.text
|
||||
onAccepted: root.state.tryUnlock()
|
||||
|
||||
Connections {
|
||||
target: root.state
|
||||
|
||||
function onCurrentTextChanged() {
|
||||
if (!passwordBox.shaking) {
|
||||
passwordBox.text = root.state.currentText;
|
||||
}
|
||||
}
|
||||
|
||||
function onShowFailureChanged() {
|
||||
if (root.state.showFailure && !passwordBox.shaking) {
|
||||
passwordBox.shaking = true;
|
||||
}
|
||||
}
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
// hint text
|
||||
Text {
|
||||
text: "Press Enter to unlock"
|
||||
color: Qt.rgba(1, 1, 1, 0.5)
|
||||
font.pointSize: 12
|
||||
horizontalAlignment: Text.AlignHCenter
|
||||
opacity: passwordBox.text.length > 0 ? 1.0 : 0.0
|
||||
|
||||
anchors {
|
||||
horizontalCenter: parent.horizontalCenter
|
||||
bottom: parent.bottom
|
||||
bottomMargin: 60
|
||||
}
|
||||
|
||||
Behavior on opacity {
|
||||
NumberAnimation {
|
||||
duration: 300
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
// testing button
|
||||
Button {
|
||||
visible: false
|
||||
text: "Emergency Unlock"
|
||||
onClicked: root.state.unlocked()
|
||||
|
||||
anchors {
|
||||
right: parent.right
|
||||
bottom: parent.bottom
|
||||
margins: 20
|
||||
}
|
||||
}
|
||||
}
|
||||
92
shell/lockscreen/LoginField.qml
Normal file
92
shell/lockscreen/LoginField.qml
Normal file
|
|
@ -0,0 +1,92 @@
|
|||
import QtQuick
|
||||
import QtQuick.Controls
|
||||
import Qt5Compat.GraphicalEffects
|
||||
|
||||
TextField {
|
||||
id: root
|
||||
color: "white"
|
||||
scale: activeFocus ? 1.05 : 1.0
|
||||
padding: 8
|
||||
focus: true
|
||||
echoMode: TextInput.Password
|
||||
inputMethodHints: Qt.ImhSensitiveData
|
||||
font.pointSize: 11
|
||||
horizontalAlignment: Text.AlignHCenter
|
||||
|
||||
background: Rectangle {
|
||||
color: Qt.rgba(1, 1, 1, 0.1)
|
||||
border.color: root.activeFocus ? Qt.rgba(1, 1, 1, 0.5) : Qt.rgba(1, 1, 1, 0.2)
|
||||
border.width: 1
|
||||
radius: 8
|
||||
|
||||
layer.enabled: true
|
||||
layer.effect: FastBlur {
|
||||
radius: 10
|
||||
transparentBorder: true
|
||||
}
|
||||
}
|
||||
|
||||
transform: Translate {
|
||||
id: shakeTransform
|
||||
x: 0
|
||||
}
|
||||
|
||||
property bool shaking: false
|
||||
|
||||
onShakingChanged: {
|
||||
if (shaking)
|
||||
shakeAnimation.start();
|
||||
}
|
||||
|
||||
Behavior on scale {
|
||||
NumberAnimation {
|
||||
duration: 200
|
||||
easing.type: Easing.OutCubic
|
||||
}
|
||||
}
|
||||
|
||||
SequentialAnimation {
|
||||
id: shakeAnimation
|
||||
|
||||
NumberAnimation {
|
||||
target: shakeTransform
|
||||
property: "x"
|
||||
to: -8
|
||||
duration: 50
|
||||
easing.type: Easing.OutQuad
|
||||
}
|
||||
NumberAnimation {
|
||||
target: shakeTransform
|
||||
property: "x"
|
||||
to: 8
|
||||
duration: 100
|
||||
easing.type: Easing.InOutQuad
|
||||
}
|
||||
NumberAnimation {
|
||||
target: shakeTransform
|
||||
property: "x"
|
||||
to: -6
|
||||
duration: 80
|
||||
easing.type: Easing.InOutQuad
|
||||
}
|
||||
NumberAnimation {
|
||||
target: shakeTransform
|
||||
property: "x"
|
||||
to: 6
|
||||
duration: 80
|
||||
easing.type: Easing.InOutQuad
|
||||
}
|
||||
NumberAnimation {
|
||||
target: shakeTransform
|
||||
property: "x"
|
||||
to: -3
|
||||
duration: 60
|
||||
easing.type: Easing.InOutQuad
|
||||
}
|
||||
|
||||
onFinished: {
|
||||
root.shaking = false;
|
||||
root.text = "";
|
||||
}
|
||||
}
|
||||
}
|
||||
1
shell/lockscreen/pam/fingerprint.conf
Normal file
1
shell/lockscreen/pam/fingerprint.conf
Normal file
|
|
@ -0,0 +1 @@
|
|||
auth sufficient pam_fprintd.so
|
||||
1
shell/lockscreen/pam/password.conf
Normal file
1
shell/lockscreen/pam/password.conf
Normal file
|
|
@ -0,0 +1 @@
|
|||
auth required pam_unix.so
|
||||
Loading…
Add table
Add a link
Reference in a new issue