mirror of
https://github.com/kossLAN/dots.git
synced 2025-11-05 06:59:50 -05:00
kossLAN
9e44812e93
remove syncthing folder bar/popops: fix menu window anims and positioning bar/popops: change anims a little and add dropshadow Update README.md widgets/coloredicon: move to colorization, looks worse but..., yea bar/popops: make popup window dissapear on menu close README: add todo list, and brief desc Update README.md Update README.md Update README.md bar/systray: issue recreate on interact bar/systray: hide popup on interact bar/systray: add arrow for entries with children bar/battery: start of battery widget wallpaper/matugen: add foot template extra sizing conditions for sys tray bar/systray: add some more margin to text update settings schema bar/workspaces: filter by monitor, switch to scriptmodel settings: fix settings lol bar/systray: fix right item feat: screenshot tool clipboard one day... feat: init lockscreen mpris: add ipc handler for multimedia keys mpris stuff save progress put shell in subdir, and add nix package move readme back woops bar/volume: make tool bar smaller greeter: init greeter greeter: fixed resource links readme: update checklist progress maybe, maybe not fix: fixed screenshot tool not working fix: bar layout issues progress save progress update track styled popup still broken but getting there still broken but getting there fix: gitignore qmlls.ini fix: remove qmlls.ini progress save new popup system new popup system new popup system more work on popups fix: mask issues on popups update readme
102 lines
2.9 KiB
QML
102 lines
2.9 KiB
QML
pragma ComponentBehavior: Bound
|
|
|
|
import QtQuick
|
|
import QtQuick.Layouts
|
|
import Qt5Compat.GraphicalEffects
|
|
import Quickshell
|
|
import Quickshell.Widgets
|
|
import Quickshell.Services.Pipewire
|
|
import ".."
|
|
|
|
Scope {
|
|
id: root
|
|
|
|
// Bind the pipewire node so its volume will be tracked
|
|
PwObjectTracker {
|
|
objects: [Pipewire.defaultAudioSink]
|
|
}
|
|
|
|
Connections {
|
|
target: Pipewire.defaultAudioSink?.audio
|
|
|
|
function onVolumeChanged() {
|
|
root.shouldShowOsd = true;
|
|
hideTimer.restart();
|
|
}
|
|
}
|
|
|
|
property bool shouldShowOsd: false
|
|
|
|
Timer {
|
|
id: hideTimer
|
|
interval: 1000
|
|
onTriggered: root.shouldShowOsd = false
|
|
}
|
|
|
|
LazyLoader {
|
|
active: root.shouldShowOsd
|
|
|
|
PopupWindow {
|
|
implicitWidth: 50
|
|
implicitHeight: 275
|
|
color: "transparent"
|
|
|
|
// An empty click mask prevents the window from blocking mouse events.
|
|
mask: Region {}
|
|
|
|
Rectangle {
|
|
anchors.fill: parent
|
|
radius: 8
|
|
color: {
|
|
let color = ShellSettings.colors["surface"];
|
|
return Qt.rgba(color.r, color.g, color.b, 0.8);
|
|
}
|
|
|
|
RowLayout {
|
|
anchors {
|
|
fill: parent
|
|
leftMargin: 10
|
|
rightMargin: 15
|
|
}
|
|
|
|
IconImage {
|
|
implicitSize: 30
|
|
source: "root:resources/volume/volume-full.svg"
|
|
}
|
|
|
|
Rectangle {
|
|
id: sliderBackground
|
|
Layout.fillWidth: true
|
|
implicitHeight: 10
|
|
radius: 20
|
|
color: {
|
|
let color = ShellSettings.colors["inverse_surface"];
|
|
return Qt.rgba(color.r, color.g, color.b, 0.5);
|
|
}
|
|
|
|
layer.enabled: true
|
|
layer.effect: OpacityMask {
|
|
maskSource: Rectangle {
|
|
width: sliderBackground.width
|
|
height: sliderBackground.height
|
|
radius: sliderBackground.radius
|
|
color: "black"
|
|
}
|
|
}
|
|
|
|
Rectangle {
|
|
color: ShellSettings.colors["primary"]
|
|
anchors {
|
|
left: parent.left
|
|
top: parent.top
|
|
bottom: parent.bottom
|
|
}
|
|
|
|
implicitWidth: parent.width * (Pipewire.defaultAudioSink?.audio.volume ?? 0)
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|